MAXQ3210所能提供的最低功耗模式为待机模式。该模式下，程序停止运行，高频晶振停止工作，电流降到微安量级。由于没有其它器件还在工作，我们需要将MAXQ3210从待机模式周期性的唤醒来测量温度。
这一要求可通过MAXQ3210的唤醒时钟实现。这一时钟依靠在待机模式仍然工作的内部8kHz低电流环形振荡器运行，能以最长两分钟的可编程间隔唤醒微控制器。这种定时唤醒对于我们的应用非常理想，在应用中可将“闹钟”设为一分钟，微控制器工作结束后接着进入待机模式以节省功耗，然后等待被唤醒再次采集数据。
;; Start the wakeup timer for 60 seconds.
move CKCN.6, #1 ; Select ring oscillator mode
waitRing:
move C, CKCN.5
jump NC, waitRing ; Wait for RGMD="1" (running from ring)
move WUT, #30000 ; 1/8kHz * 30000 * 16 = 60 seconds
move WUTC, #0101b ; Start the wakeup timer (running from ring)
move IV, #wakeUPINt ; Set interrupt handler for wakeup interrupt
move IMR.0, #1 ; Enable interrupts from module 0
move IC.0, #1 ; Globally enable interrupts
move PD0.7, #0 ; Turn off output mode for LED pin
move PO0.7, #1 ; Return to default state (weak pullup)
move CKCN.4, #1 ; Go into Stop mode, wait for wakeup int
nop
jump mainLoop ; Back for another round
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
wakeUpInt:
move PD0.7, #1 ; Turn on output mode for LED port pin
move PO0.7, #0 ; Light the LED
move CKCN.6, #1 ; Select ring oscillator mode
wakeUp_ring:
move C, CKCN.5
jump NC, wakeUp_ring ; Wait for RGMD="1" (running from ring)
move LC[0], #4000
djnz LC[0], $
move PO0.7, #1 ; LED off
move LC[0], #4000
djnz LC[0], $
move WUTC, #0 ; Clear wakeup timer flag
move CKCN.6, #0 ; Select Crystal mode
wakeUp_xtal:
move C, CKCN.5
jump C, wakeUp_xtal ; Wait for RGMD="0" (running from crystal)
move GRL, #'W'
call TxCharBB
move GRL, #'U'
call TxCharBB
move GRL, #0Dh
call TxCharBB
move GRL, #0Ah
call TxCha
www.55dianzi.com
rBB
reti
上传温度记录数据
每次上电复位后，应用程序向主机系统发送温度记录数据。数据通过10位异步串行接口以9600bps的速率发送(1位开始位，8位数据位，1位停止位)。MAXQ3210不带硬件UART串口，需要使用一个端口引脚模拟实现。由于本应用只需发送，不需接收，所以实现起来比较简单。
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Function : TxCharBB
;; Description : Transmits a 10-bit serial character (bit-banged)
;; over P0.0.
;; Inputs : GRL - Character to send
;; Outputs : None
;; Destroys : PSF, AP, APC, A[0], LC[0], LC[1]
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
TxCharBB:
move APC, #080h ; Standard mode, select A[0] as ACC
move Acc, GRL
move PO0.0, #0 ; START bit low
move LC[0], #BITLOOP
djnz LC[0], $
move LC[1], #8 ; 8 bits
TxCharBB_bitLoop:
rrc ; Get the next bit
jump C, TxCharBB_one
TxCharBB_zero:
move PO0.0, #0
sjump TxCharBB_next
TxCharBB_one:
move PO0.0, #1
TxCharBB_next:
move LC[0], #BITLOOP
djnz LC[0], $
djnz LC[1], TxCharBB_bitLoop
move PO0.0, #1 ; STOP bit high
move LC[0], #BITLOOP
djnz LC[0], $
move LC[0], #BITLOOP
djnz LC[0], $
ret
要把温度数据从带符号的2进制、8位摄氏度数值转换成容易识别的ASCII码、华氏度数值，还需要增加较多代码，但这些代码简单易懂。使用BCD (二进制编码的十进制)运算规则执行二进制到十进制的转换，同时完成摄氏度到华氏度的转换。
move GR, @DP[0] ; Get the current entry
move Acc, GRH ; Check the high byte
jump Z, endOutput ; If it's zero we're done
move A[15], GRL ; Save the low byte (temp value)
move A[7], #0 ; Hundreds = 0
move A[6], #0 ; Tens = 0
move A[5], #0 ; Ones = 0
move A[4], #0 ; Tenths = 0
move A[3], #0 ; Add 01.8 per degree C
move A[2], #1
move A[1], #8
move Acc, A[15] ; s6543210
jump S, tempNegC
tempPosC:
move GRL, #'+'
jump Z, tempPrint
move LC[0], Acc
tempPosC_loop:
call AddBCD
djnz LC[0], tempPosC_loop
move A[3], #3
move A[2], #2
move A[1], #0 ; Add 32.0
call AddBCD
jump tempPrint
tempNegC:
move GRL, #'-'
neg
jump Z, tempPrint ; Negative zero
jump S, tempPrint ; -128 is outside the sensor range anyhow
move LC[0], Acc
tempNegC_loop:
call AddBCD
djnz LC[0], tempNegC_loop
move A[3], #3
move A[2], #2
move A[1], #0 ; Subtract 32.0
call SubBCD
jump NC, tempPrint
move GRL, #'+' ; Back to
www.55dianzi.com
positive again
jump tempPrint
tempPrint:
call TxCharBB ; Print plus/minus sign
call TxTempBB ; Print temperature value + newline
call IncDP0_EE ; Move to the next entry
由于MAXQ3210的端口输出采用5V电平，在与PC的COM串口连接之前必须使用外部器件(如MAX233ACWP)对输出进行电平转换。完成这一转换后，可以使用任何标准终端仿真程序接收应用输出的数据。
RST
DS1822 Detected : 22A9CC15000000E5
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 59.0
+ 62.6
+ 69.8
+ 59.0
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 57.2
+ 55.4
+ 55.4
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
应用功能扩展
MAXQ3210具有1k x 16 (1024字)的EEPROM程序存储空间，演示代码只占用了其中的60%至70%。可对应用代码进一步优化，使其仅占用50%的程序存储空间。开发了应用的核心功能后，可增加许多额外功能，使其成为功能完备的环境检测系统。
多传感器。可以轻松地扩充 1-Wire 子程序，使其能够访问多个DS1822温度传感器，这些传感器可以分别与单独的端口连接(每端口接1个器件)，或者在单根线上挂一组器件(多点配置)。多点配置结构比较复杂，但能够使MAXQ3210连接更多的器件。
多种传感器类型。应用可以连接多种不同类型的1-Wire传感器，以测量不同环境参数，包括：湿度(DS1923温度/湿度记录仪)、物理开关(DS2401硅序列号)，或使用模数转换器(DS2450，1-Wire接口、四通道、A/D转换器)的通用传感器。更多信息见Maxim IC网站的1-Wire/iButton产品页面。
声音告警。MAXQ3210内置压电扬声器驱动电路，因此可以非常简单地加入高分贝扬声器。当温度转换结果高于或低于指定门限后，将发出告警声。
增加记录容量。应用可以按照写数据EEPROM的方式将数据写到未使用的程序EEPROM中。如果应用代码足够小，可以用一部分程序EEPROM来存储更多的温度转换结果，进而记录更长时间的温度数据。
双向串行 通信 。通过位模拟方式实现双向串行端口，要比仅仅实现发送端口更复杂，但MAXQ3210仍可轻松实现。有了双向端口，主机可以请求MAXQ3210上传记录数据，设置配置数据(如DS1822的温度分辨率)，按需访问特定的传感器，甚至可以通过串行接口更新MAXQ3210的固件。
结论
小封装，低功耗，I/O灵活的MAXQ3210是电池供电的 环境监测 应用的理想选择。许多1-Wire传感器可被用来测量温度、湿度等环境参数，而这些传感器又可仅通过一个端口实现与MAX3210的接口。最后，数据还可以被存贮在MAXQ3210自带的非易失EEPROM存储器中，供以后查询和分析。
本文关键字：记录仪 DSP/FPGA技术，单片机-工控设备 - DSP/FPGA技术
